GuShH's DevBlog » Programming

(PB) String Between Characters

GuShH — Tue, 26 Apr 2011 12:30:07 +0000

This is a small purebasic function used to retrieve a string between two known characters, it also allows you to provide a starting position.

Procedure.s str_between_char( *Source.CHARACTER, First.C, Last.C, StartAt.i = 0 )
	Define.i dwLength
 
	*Source + (StartAt * SizeOf(CHARACTER))
	Repeat
		If *Source\c = First ; If this character matches the First character
			*Source + SizeOf(CHARACTER)
			dwLength = *Source
			Repeat ; Repeat until we find an occurrance with the Last character
				*Source + SizeOf(CHARACTER)
			Until *Source\c = Last
			dwLength = (*Source - dwLength)
			ProcedureReturn PeekS( *Source - dwLength, dwLength ) ; Peek the output string
			Break
		EndIf
		*Source + SizeOf(CHARACTER)
	Until *Source\c = #Null
 
EndProcedure

Example use:

Define.s str 		= "dd(hallo)xyz(a)"
Define.s result 	= str_between_char(@str, '(', ')', 2)
Debug result

If you’re working on a parser or similar project this will sure come in handy.
Enjoy!

Away from the IDEs.

GuShH — Sat, 12 Sep 2009 08:43:05 +0000

I had in mind to share a bunch of my libraries throughout the course of this week, however real life kicked-in and prevented me from doing any of it. In a few days I will hopefully start posting the promised code. Keep in mind though, I’ve been studying electronics lately (I find it fascinating) so any spare time is likely to be spent on that as well.

Let’s see if I can get some well deserved rest now…

TimeLapse lib

GuShH — Wed, 05 Aug 2009 18:48:02 +0000

This little lib is used to keep track of time using the low resolution timer provided by the OS (in Windows “GetTickCount”). The goal of this type of library is to encapsulate timing actions. It was originally designed for game development in mind but needless to say you can use it and adapt it to your own needs.

Basically you define a time interval as you create the “timelapse” instance. Every time you call the update function a simple check determines whether the time was reached or not. This is trivial, but encapsulating it makes sense. Specially if you plan to create an animation system in the future!

The code:

EnableExplicit
 
Prototype.i TimeLapse_Callback( *this.i )
 
Structure TIMELAPSE
	old_time.i			; Stores the "old" time value.
	new_time.i			; Stores the "new" time value.
	time_out.i			; Time period for the TimeLapse , in ms.
	*callback.TimeLapse_Callback	; User callback.
	userdata.i			; User data.
EndStructure
 
CompilerSelect #PB_Compiler_OS
	CompilerCase #PB_OS_Windows
		Macro _time() : timeGetTime_()		: EndMacro
	CompilerDefault
		Macro _time() : ElapsedMilliseconds()	: EndMacro
CompilerEndSelect
 
Procedure.i TimeLapseCreate( Timeout.i, *Callback.TimeLapse_Callback = #Null, UserData.i = #Null )
 
	Define.TimeLapse  *this = AllocateMemory( SizeOf(TimeLapse ) )
 
	If *this
 
		With *this
			\new_time 	= _time()
			\old_time 	= *this\new_time
			\time_out	= Timeout
			\callback	= *Callback
			\userdata	= UserData
		EndWith
 
		ProcedureReturn *this
 
	EndIf
 
EndProcedure
 
Procedure.i TimeLapseDestroy( *this.TIMELAPSE  )
 
	If *this
 
		FreeMemory(*this)
		*this = #Null
		ProcedureReturn *this
 
	EndIf
 
EndProcedure
 
Procedure.i TimeLapseUpdate( *this.TIMELAPSE  )
 
	If *this
 
		*this\new_time = _time()
 
		If ((*this\new_time - *this\old_time) => *this\time_out)
 
			*this\old_time = *this\new_time
 
			If *this\callback
				ProcedureReturn *this\callback( *this )
			EndIf
 
			ProcedureReturn #True
 
		EndIf
 
	EndIf
 
EndProcedure
 
 
; Helper routines
 
Procedure.i TimeLapseSet( *this.TIMELAPSE , Timeout.i )
 
 	If Timeout > 0
		*this\time_out = Timeout
	EndIf
 
EndProcedure
 
Procedure.i TimeLapseGet( *this.TIMELAPSE  )
 
 	ProcedureReturn *this\time_out
 
EndProcedure

Example:

If OpenConsole()
	Define.TIMELAPSE  *test_timer  = TimeLapseCreate( 500 )
	Repeat
 
		If TimeLapseUpdate( *test_timer  )
			PrintN(" Timer says hi!" )
		EndIf
 
		Delay(10)
	Until Inkey() = Chr(27)
	CloseConsole()
EndIf
End

The nice thing about this library is the ability to use callbacks. Whenever a callback is defined, once the timer reaches the maximum allowed time-lapse, it’ll return by executing the callback.

In the callback you can do anything you want; From simple event triggering to manipulating another timer depending on XYZ conditions: it’s up to you!.

Just keep in mind: Always return “true” unless you want to invalidate the update call.

Here is a more advanced example with a callback, user data and multiple timers:

Procedure.i MyCallback( *this.TIMELAPSE  )
 
	; It's imperative that you return #true (1) in your callbacks if you want the "Update" calls to pass once the timeout is reached.
	; This is a design choice for flexibility and nothing else.
 
	ConsoleColor(Random(15), Random(15))
	PrintN(" Hi from the callback! ")
 
	PrintN( " The other timer is set to: " + Str( TimeLapseGet( *this\userdata ) ) + "ms" )
	PrintN( " ...Reducing the time interval down by 50 ms... " )
 
	TimeLapseSet( *this\userdata, TimeLapseGet( *this\userdata ) - 50 )
	ConsoleColor(15, 0)
 
	ProcedureReturn #True
 
EndProcedure
 
Define.TIMELAPSE  *timer_one 	= TimeLapseCreate( 500 )				; The first TimeLapse , nothing special.
Define.TIMELAPSE  *timer_two 	= TimeLapseCreate( 2000, @MyCallback(), *timer_one )	; The second TimeLapse , it manipulates the first one through a callback.
Define.TIMELAPSE  *timer_three	= TimeLapseCreate( 20*1000 )				; This TimeLapse  will simply let us exit the example after the set time.
 
If OpenConsole()
 
	EnableGraphicalConsole(1)
	ConsoleColor(15, 0)
 
	Define.i quit = #False
 
	Repeat
 
		If TimeLapseUpdate( *timer_three )
			quit = #True
		Else
			If TimeLapseUpdate( *timer_one )
				PrintN("timer_one: " + Str(*timer_one\time_out) + "ms reached.")
			EndIf
			If TimeLapseUpdate( *timer_two )
				PrintN("timer_two: " + Str(*timer_two\time_out) + "ms reached.")
			EndIf
		EndIf
 
		Delay(10)
 
	Until Inkey() = Chr(27) Or quit 
 
	PrintN( "timer_three: The example finished." )
 
	TimeLapseDestroy(*timer_one)
	TimeLapseDestroy(*timer_two)
	TimeLapseDestroy(*timer_three)
 
	Input()
	CloseConsole()
 
EndIf
End

The examples are crude, but they show every function in the library.
Should you have any questions, feel free to ask.

I’ll soon post the “Animation” lib that depends on “TimeLapse”.

Cheers.

Centered MessageRequester() / MessageBox()

GuShH — Thu, 02 Jul 2009 16:25:00 +0000

As usual, I was browsing the PureBasic forums to see what was new, nothing much (heh…) but something caught my attention, the fact that some user requested for the IDE’s message dialogs to be “centered” ( because he had multiple displays and the messages would appear in between them ) just to get shit-faced by an actual staff member!

You can’t just say “it’s Microsoft’s fault” — Are you in some sort of mac-only cleanse?, What’s your #%&%#$ problem?!

Those who “pass the ball” (as the user suggested) are part of the problem. You, being a programmer can certainly code a simple CBT hook, right?. Are you against hooks, perhaps – you are a purist, I hear… Sorry, but sometimes solutions are “dirty” and you have to live with them.

Just for the record, I too use a split-screen and I find it annoying that dialog boxes are not centered to their parent.

I certainly think that this sort of behavior is not good for a business, but then again they’ve been cat-walking away from reality for years now (Look at their website if not, look at the fact that they haven’t implemented basic functionality to their language and by basic I mean a proper container library and whatnot!). Most of their user-base consists of people who are afraid of real, world-class languages. That’s my opinion, take it or leave it.

But before you throw crap at me do remember that I support them, I just don’t like the way they’re doing things. Pretty much like Apple does (they do crap) however the fanboys don’t realize this and they see any criticism as bad for the company image, when in fact what damages the company is that nonsense wall they put up when anybody, and I do mean “anybody” says “anything” that appears to be “against” their product/s.

Even if you don’t like it at least have the decency to hear those who are genuinely interested in your product, those who are giving away (and for free) true and useful suggestions for you to improve them. I don’t give a damn about this particular user but I do care when a so called company does this sort of things to their own users, it’s just uncalled for and plainly unprofessional.

Have a nice day, code follows.

; This snippet was based on the following code by Microsoft:
; http://support.microsoft.com/kb/180936
EnableExplicit ; The only way to go.
 
Procedure.i CenterMsgCallBack( uMsg.i, wParam.i, lParam.i ) 
 
	Select uMsg
		Case #HCBT_ACTIVATE
 
			Define.RECT typFormRect, typRectMsg
			Define.i plMsgHook, hWnd
			Define.i lxPos, lyPos
 
			hWnd = GetParent_(wParam) 																																																		; the parent will be the callee
 
			If hWnd 																																																											; can't hurt to check.
 
				plMsgHook 	= GetWindowLong_( hWnd, #GWL_USERDATA ) 																																				; get the hook address
 
				If plMsgHook 																																																								; can't hurt to check.
 
					GetWindowRect_( hWnd, typFormRect )
					GetWindowRect_( wParam, typRectMsg )
 
					lxPos = (typFormRect\Left + (typFormRect\Right - typFormRect\Left) / 2) - ((typRectMsg\Right - typRectMsg\Left) / 2)
					lyPos = (typFormRect\Top  +	(typFormRect\Bottom - typFormRect\Top) / 2) - ((typRectMsg\Bottom - typRectMsg\Top) / 2)
 
					SetWindowPos_( wParam, 0, lxPos, lyPos, 0, 0,	#SWP_NOSIZE | #SWP_NOZORDER | #SWP_NOACTIVATE ) 														; position the window.
					UnhookWindowsHookEx_(plMsgHook) 																																													; release the hook.
					SetWindowLong_( hWnd, #GWL_USERDATA, #Null ) 																																							; unset the user data.
 
				EndIf
 
			EndIf
	EndSelect
 
EndProcedure 
 
Procedure.i CenteredMessageRequester( Title.s, Text.s, Flags.i=#Null, hWnd.i=#Null )
 
	Define.i lInstance, lThreadID, plMsgHook
 
	If Not hWnd
		hWnd = WindowID( GetActiveWindow() )
	EndIf
 
	If hWnd
 
		lInstance = GetWindowLong_( hWnd, #GWL_HINSTANCE )
		lThreadID = GetCurrentThreadId_()
 
		If lInstance And lThreadID 																																																			; just to make sure, can't hurt.
 
			plMsgHook = SetWindowsHookEx_(#WH_CBT, @CenterMsgCallBack(), lInstance, lThreadID) 																						; create the cbt hook.
			SetWindowLong_(	hWnd, #GWL_USERDATA, plMsgHook ) 																																							; save the hook address, we'll need it to release it.
 
			ProcedureReturn MessageBox_( hWnd, Text, Title, Flags )																																				; finally, create the message box.
 
		EndIf
	EndIf
 
EndProcedure

And a small example:

OpenWindow( 0, 500, 200, 400, 200, "testing" )																																											; test window
MessageRequester( ":(", "I'm a normal messagebox", #MB_APPLMODAL | #MB_ICONERROR )																									; conventional msgbox
CenteredMessageRequester( ":)", "I'm a centered messagebox!", #MB_APPLMODAL | #MB_ICONEXCLAMATION )																	; our centered msgbox.

The “Programmer” can now copy&paste and compile.

Cheers.

PS: You can also find the source in here: http://gushh.net/dev/?file=pb/centermessagebox.pb As usual, that’s my code repository for PB.

Going from Basic to the real world.

GuShH — Fri, 06 Mar 2009 23:17:19 +0000

You’ve been coding in *Basic for a while now, you feel you know it all and there’s nothing else to get from it. Well, that wouldn’t be a strange scenario, it happens to anyone who has been misled into the programming world to begin with!

The problem with the Basic languages is that they were conceived as a learning step and nothing else. Some of them try to stretch the bar, failing miserably in the process.

Now, don’t get me wrong I like them, But they’re not a world-class programming environment nor language nor compiler. Why else do you think that no one hires for *Basic?, because it practically doesn’t exist in the real world.

As a learning tool if it served it’s purpose then applaud and make yourself a favor: move on.

The next step: Choosing a real language.

Languages are like fruit, you bake an apple cake with apples and you make an orange mousse with oranges. You don’t go around faking the apple cake with another fruit because then, it wouldn’t be an apple cake to begin with. How is this example any good?, it’s the same as saying “choosing the right tool for the right job”. I just like to cook and present bad analogies.

Alas, your big project won’t go anywhere in it’s current state but porting towards a world-class language isn’t hard at all, once you’ve mastered the target language. This could take some time, specially with C++ (some say, you will never stop learning it – isn’t this amazing?, you can’t get bored with it!).

But, the real purpose for moving on is not only because no one will ever hire a “basic” programmer, It’s simply because you shouldn’t have to put up with any language limitations to write your dream code. And also, because the support for world-class languages is ten orders of magnitude better than your current “Official forums” and “Official IRC Channel” for your beloved Basic variant.

I always say, those “Neo Basic” languages are nothing but the retarded bastard child of a couple of bad programmers who couldn’t get their facts straight to begin with. Either that, or they needed some quick beer money. You choose. The truth is, you can learn how to program with better languages (I hear Python, C#, etc) and never, ever, have to put up with a Basic language at all. It’s not an ideal-world scenario, it’s the real world and you can do it right now, no one forces you to a lesser language but yourself.

Now, for prototyping, that’s another story; see… almost any language is good for prototyping!. Just don’t forget that those libraries presented on that *Basic language could well be available in a world-class language already. So unless you’re trying to escape a strict syntax or you already have a bunch of code templates done, don’t go for a lesser language.

So really, the only reason you’d try and code in a *Basic language is for nostalgia’s sake. Either that or you have a bad case of masochism. But I don’t blame you, I sometimes fire up some sort of Basic compiler just for fun, if any.

As I said – and I don’t think I’m the only one with this point of view – You should open your eyes and see what’s really out there, stop limiting yourself. Put that bucket of excuses in a hole and bury it, live again.